8943a5a28e
The parent file has already set a variable for it. Change-Id: I90ddda355a580f44ea7e1e44cc7df717fa0a8b7b Reviewed-by: Alexander Neundorf <neundorf@kde.org> Reviewed-by: Stephen Kelly <stephen.kelly@kdab.com>
253 lines
10 KiB
CMake
253 lines
10 KiB
CMake
#=============================================================================
|
|
# Copyright 2005-2011 Kitware, Inc.
|
|
# All rights reserved.
|
|
#
|
|
# Redistribution and use in source and binary forms, with or without
|
|
# modification, are permitted provided that the following conditions
|
|
# are met:
|
|
#
|
|
# * Redistributions of source code must retain the above copyright
|
|
# notice, this list of conditions and the following disclaimer.
|
|
#
|
|
# * Redistributions in binary form must reproduce the above copyright
|
|
# notice, this list of conditions and the following disclaimer in the
|
|
# documentation and/or other materials provided with the distribution.
|
|
#
|
|
# * Neither the name of Kitware, Inc. nor the names of its
|
|
# contributors may be used to endorse or promote products derived
|
|
# from this software without specific prior written permission.
|
|
#
|
|
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
|
|
# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
|
|
# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
|
|
# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
|
|
# HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
|
|
# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
|
|
# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
|
|
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
|
|
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
|
|
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
|
|
# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
|
|
#=============================================================================
|
|
|
|
######################################
|
|
#
|
|
# Macros for building Qt files
|
|
#
|
|
######################################
|
|
|
|
include(CMakeParseArguments)
|
|
|
|
# macro used to create the names of output files preserving relative dirs
|
|
macro(QT5_MAKE_OUTPUT_FILE infile prefix ext outfile )
|
|
string(LENGTH ${CMAKE_CURRENT_BINARY_DIR} _binlength)
|
|
string(LENGTH ${infile} _infileLength)
|
|
set(_checkinfile ${CMAKE_CURRENT_SOURCE_DIR})
|
|
if(_infileLength GREATER _binlength)
|
|
string(SUBSTRING "${infile}" 0 ${_binlength} _checkinfile)
|
|
if(_checkinfile STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
|
|
file(RELATIVE_PATH rel ${CMAKE_CURRENT_BINARY_DIR} ${infile})
|
|
else()
|
|
file(RELATIVE_PATH rel ${CMAKE_CURRENT_SOURCE_DIR} ${infile})
|
|
endif()
|
|
else()
|
|
file(RELATIVE_PATH rel ${CMAKE_CURRENT_SOURCE_DIR} ${infile})
|
|
endif()
|
|
if(WIN32 AND rel MATCHES "^[a-zA-Z]:") # absolute path
|
|
string(REGEX REPLACE "^([a-zA-Z]):(.*)$" "\\1_\\2" rel "${rel}")
|
|
endif()
|
|
set(_outfile "${CMAKE_CURRENT_BINARY_DIR}/${rel}")
|
|
string(REPLACE ".." "__" _outfile ${_outfile})
|
|
get_filename_component(outpath ${_outfile} PATH)
|
|
get_filename_component(_outfile ${_outfile} NAME_WE)
|
|
file(MAKE_DIRECTORY ${outpath})
|
|
set(${outfile} ${outpath}/${prefix}${_outfile}.${ext})
|
|
endmacro()
|
|
|
|
|
|
macro(QT5_GET_MOC_FLAGS _moc_flags)
|
|
set(${_moc_flags})
|
|
get_directory_property(_inc_DIRS INCLUDE_DIRECTORIES)
|
|
|
|
if(CMAKE_INCLUDE_CURRENT_DIR)
|
|
list(APPEND _inc_DIRS ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_BINARY_DIR})
|
|
endif()
|
|
|
|
foreach(_current ${_inc_DIRS})
|
|
if("${_current}" MATCHES "\\.framework/?$")
|
|
string(REGEX REPLACE "/[^/]+\\.framework" "" framework_path "${_current}")
|
|
set(${_moc_flags} ${${_moc_flags}} "-F${framework_path}")
|
|
else()
|
|
set(${_moc_flags} ${${_moc_flags}} "-I${_current}")
|
|
endif()
|
|
endforeach()
|
|
|
|
get_directory_property(_defines COMPILE_DEFINITIONS)
|
|
foreach(_current ${_defines})
|
|
set(${_moc_flags} ${${_moc_flags}} "-D${_current}")
|
|
endforeach()
|
|
|
|
if(WIN32)
|
|
set(${_moc_flags} ${${_moc_flags}} -DWIN32)
|
|
endif()
|
|
endmacro()
|
|
|
|
|
|
# helper macro to set up a moc rule
|
|
macro(QT5_CREATE_MOC_COMMAND infile outfile moc_flags moc_options)
|
|
# For Windows, create a parameters file to work around command line length limit
|
|
if(WIN32)
|
|
# Pass the parameters in a file. Set the working directory to
|
|
# be that containing the parameters file and reference it by
|
|
# just the file name. This is necessary because the moc tool on
|
|
# MinGW builds does not seem to handle spaces in the path to the
|
|
# file given with the @ syntax.
|
|
get_filename_component(_moc_outfile_name "${outfile}" NAME)
|
|
get_filename_component(_moc_outfile_dir "${outfile}" PATH)
|
|
if(_moc_outfile_dir)
|
|
set(_moc_working_dir WORKING_DIRECTORY ${_moc_outfile_dir})
|
|
endif()
|
|
set(_moc_parameters_file ${outfile}_parameters)
|
|
set(_moc_parameters ${moc_flags} ${moc_options} -o "${outfile}" "${infile}")
|
|
string(REPLACE ";" "\n" _moc_parameters "${_moc_parameters}")
|
|
file(WRITE ${_moc_parameters_file} "${_moc_parameters}")
|
|
add_custom_command(OUTPUT ${outfile}
|
|
COMMAND ${Qt5Core_MOC_EXECUTABLE} @${_moc_outfile_name}_parameters
|
|
DEPENDS ${infile}
|
|
${_moc_working_dir}
|
|
VERBATIM)
|
|
else()
|
|
add_custom_command(OUTPUT ${outfile}
|
|
COMMAND ${Qt5Core_MOC_EXECUTABLE}
|
|
ARGS ${moc_flags} ${moc_options} -o ${outfile} ${infile}
|
|
DEPENDS ${infile} VERBATIM)
|
|
endif()
|
|
endmacro()
|
|
|
|
|
|
function(QT5_GENERATE_MOC infile outfile )
|
|
# get include dirs and flags
|
|
qt5_get_moc_flags(moc_flags)
|
|
get_filename_component(abs_infile ${infile} ABSOLUTE)
|
|
set(_outfile "${outfile}")
|
|
if(NOT IS_ABSOLUTE "${outfile}")
|
|
set(_outfile "${CMAKE_CURRENT_BINARY_DIR}/${outfile}")
|
|
endif()
|
|
qt5_create_moc_command(${abs_infile} ${_outfile} "${moc_flags}" "")
|
|
set_source_files_properties(${outfile} PROPERTIES SKIP_AUTOMOC TRUE) # dont run automoc on this file
|
|
endfunction()
|
|
|
|
|
|
# qt5_wrap_cpp(outfiles inputfile ... )
|
|
|
|
function(QT5_WRAP_CPP outfiles )
|
|
# get include dirs
|
|
qt5_get_moc_flags(moc_flags)
|
|
|
|
set(options)
|
|
set(oneValueArgs)
|
|
set(multiValueArgs OPTIONS)
|
|
|
|
cmake_parse_arguments(_WRAP_CPP "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
|
|
|
|
set(moc_files ${_WRAP_CPP_UNPARSED_ARGUMENTS})
|
|
set(moc_options ${_WRAP_CPP_OPTIONS})
|
|
foreach(it ${moc_files})
|
|
get_filename_component(it ${it} ABSOLUTE)
|
|
qt5_make_output_file(${it} moc_ cpp outfile)
|
|
qt5_create_moc_command(${it} ${outfile} "${moc_flags}" "${moc_options}")
|
|
list(APPEND ${outfiles} ${outfile})
|
|
endforeach()
|
|
set(${outfiles} ${${outfiles}} PARENT_SCOPE)
|
|
endfunction()
|
|
|
|
|
|
# qt5_add_resources(outfiles inputfile ... )
|
|
|
|
function(QT5_ADD_RESOURCES outfiles )
|
|
|
|
set(options)
|
|
set(oneValueArgs)
|
|
set(multiValueArgs OPTIONS)
|
|
|
|
cmake_parse_arguments(_RCC "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
|
|
|
|
set(rcc_files ${_RCC_UNPARSED_ARGUMENTS})
|
|
set(rcc_options ${_RCC_OPTIONS})
|
|
|
|
foreach(it ${rcc_files})
|
|
get_filename_component(outfilename ${it} NAME_WE)
|
|
get_filename_component(infile ${it} ABSOLUTE)
|
|
get_filename_component(rc_path ${infile} PATH)
|
|
set(outfile ${CMAKE_CURRENT_BINARY_DIR}/qrc_${outfilename}.cpp)
|
|
|
|
set(_RC_DEPENDS)
|
|
if(EXISTS "${infile}")
|
|
# parse file for dependencies
|
|
# all files are absolute paths or relative to the location of the qrc file
|
|
file(READ "${infile}" _RC_FILE_CONTENTS)
|
|
string(REGEX MATCHALL "<file[^<]+" _RC_FILES "${_RC_FILE_CONTENTS}")
|
|
foreach(_RC_FILE ${_RC_FILES})
|
|
string(REGEX REPLACE "^<file[^>]*>" "" _RC_FILE "${_RC_FILE}")
|
|
if(NOT IS_ABSOLUTE "${_RC_FILE}")
|
|
set(_RC_FILE "${rc_path}/${_RC_FILE}")
|
|
endif()
|
|
set(_RC_DEPENDS ${_RC_DEPENDS} "${_RC_FILE}")
|
|
endforeach()
|
|
# Since this cmake macro is doing the dependency scanning for these files,
|
|
# let's make a configured file and add it as a dependency so cmake is run
|
|
# again when dependencies need to be recomputed.
|
|
qt5_make_output_file("${infile}" "" "qrc.depends" out_depends)
|
|
configure_file("${infile}" "${out_depends}" COPY_ONLY)
|
|
else()
|
|
# The .qrc file does not exist (yet). Let's add a dependency and hope
|
|
# that it will be generated later
|
|
set(out_depends)
|
|
endif()
|
|
|
|
add_custom_command(OUTPUT ${outfile}
|
|
COMMAND ${Qt5Core_RCC_EXECUTABLE}
|
|
ARGS ${rcc_options} -name ${outfilename} -o ${outfile} ${infile}
|
|
MAIN_DEPENDENCY ${infile}
|
|
DEPENDS ${_RC_DEPENDS} "${out_depends}" VERBATIM)
|
|
list(APPEND ${outfiles} ${outfile})
|
|
endforeach()
|
|
set(${outfiles} ${${outfiles}} PARENT_SCOPE)
|
|
endfunction()
|
|
|
|
|
|
if (NOT CMAKE_VERSION VERSION_LESS 2.8.9)
|
|
macro(qt5_use_modules _target _link_type)
|
|
if (NOT TARGET ${_target})
|
|
message(FATAL_ERROR "The first argument to qt5_use_modules must be an existing target.")
|
|
endif()
|
|
if ("${_link_type}" STREQUAL "LINK_PUBLIC" OR "${_link_type}" STREQUAL "LINK_PRIVATE" )
|
|
set(_qt5_modules ${ARGN})
|
|
set(_qt5_link_type ${_link_type})
|
|
else()
|
|
set(_qt5_modules ${_link_type} ${ARGN})
|
|
endif()
|
|
|
|
if ("${_qt5_modules}" STREQUAL "")
|
|
message(FATAL_ERROR "qt5_use_modules requires at least one Qt module to use.")
|
|
endif()
|
|
|
|
foreach(_module ${_qt5_modules})
|
|
if (NOT Qt5${_module}_FOUND)
|
|
find_package(Qt5${_module} PATHS ${_qt5Core_install_prefix} NO_DEFAULT_PATH)
|
|
if (NOT Qt5${_module}_FOUND)
|
|
message(FATAL_ERROR "Can not use \"${_module}\" module which has not yet been found.")
|
|
endif()
|
|
endif()
|
|
target_link_libraries(${_target} ${_qt5_link_type} ${Qt5${_module}_LIBRARIES})
|
|
set_property(TARGET ${_target} APPEND PROPERTY INCLUDE_DIRECTORIES ${Qt5${_module}_INCLUDE_DIRS})
|
|
set_property(TARGET ${_target} APPEND PROPERTY COMPILE_DEFINITIONS ${Qt5${_module}_COMPILE_DEFINITIONS})
|
|
set_property(TARGET ${_target} APPEND PROPERTY COMPILE_DEFINITIONS_RELEASE QT_NO_DEBUG)
|
|
|
|
if (Qt5_POSITION_INDEPENDENT_CODE)
|
|
set_property(TARGET ${_target} PROPERTY POSITION_INDEPENDENT_CODE ${Qt5_POSITION_INDEPENDENT_CODE})
|
|
endif()
|
|
endforeach()
|
|
endmacro()
|
|
endif()
|