Amends f9e48854af4a25f13f593dd151071c8eda53b65f Change-Id: Iea525c70cca9873c0f3d96967af6cd95d57cac9b Reviewed-by: Alexandru Croitor <alexandru.croitor@qt.io> (cherry picked from commit 4d7ba44e4da94497231ebded59b1564597857eed) Reviewed-by: Qt Cherry-pick Bot <cherrypick_bot@qt-project.org>
44 lines
1.3 KiB
CMake
44 lines
1.3 KiB
CMake
# The function returns location of the imported 'tool', returns an empty string if tool is not
|
|
# imported.
|
|
function(__qt_internal_get_tool_imported_location out_var tool)
|
|
unset(${out_var})
|
|
if("${tool}" MATCHES "^Qt[0-9]?::.+$")
|
|
# The tool target has namespace already
|
|
set(target ${tool})
|
|
else()
|
|
set(target ${QT_CMAKE_EXPORT_NAMESPACE}::${tool})
|
|
endif()
|
|
|
|
if(NOT TARGET ${target})
|
|
message(FATAL_ERROR "${target} is not a target.")
|
|
endif()
|
|
|
|
get_target_property(is_imported ${target} IMPORTED)
|
|
if(NOT is_imported)
|
|
set(${out_var} "" PARENT_SCOPE)
|
|
return()
|
|
endif()
|
|
|
|
get_target_property(configs ${target} IMPORTED_CONFIGURATIONS)
|
|
list(TRANSFORM configs PREPEND _)
|
|
# Well-known configuration types
|
|
list(APPEND configs
|
|
_RELWITHDEBINFO
|
|
_RELEASE
|
|
_MINSIZEREL
|
|
_DEBUG
|
|
)
|
|
list(REMOVE_DUPLICATES configs)
|
|
# Look for the default empty configuration type at the first place.
|
|
list(PREPEND configs "")
|
|
|
|
foreach(config ${configs})
|
|
get_target_property(${out_var} ${target} "IMPORTED_LOCATION${config}")
|
|
if(${out_var})
|
|
break()
|
|
endif()
|
|
endforeach()
|
|
|
|
set(${out_var} "${${out_var}}" PARENT_SCOPE)
|
|
endfunction()
|