ccb68f1d28
- GHS compiler doesn't have -Wextra flag and it leads to huge count of warnings. Change-Id: Id2ba654a49fb163bebc75e3a22ecaa1895ecdbe8 Reviewed-by: Alexandru Croitor <alexandru.croitor@qt.io> (cherry picked from commit 05acb9e2b9cc6a830394f55f5dff6c4a18bc17b0) Reviewed-by: Qt Cherry-pick Bot <cherrypick_bot@qt-project.org>
30 lines
1.2 KiB
CMake
30 lines
1.2 KiB
CMake
# Set warnings. All compilers except MSVC support -Wall -Wextra
|
|
# Allow opting out by setting a QT_COMPILE_WARNINGS_OFF property on targets. This would be the
|
|
# equivalent of qmake's CONFIG += warn_off.
|
|
|
|
set(_qt_compiler_warning_flags_on "")
|
|
set(_qt_compiler_warning_flags_off "")
|
|
|
|
if (MSVC)
|
|
list(APPEND _qt_compiler_warning_flags_on /W3)
|
|
list(APPEND _qt_compiler_warning_flags_off -W0)
|
|
else()
|
|
if(CMAKE_CXX_COMPILER_ID STREQUAL "GHS") # There is no -Wextra flag for GHS compiler.
|
|
list(APPEND _qt_compiler_warning_flags_on -Wall)
|
|
else()
|
|
list(APPEND _qt_compiler_warning_flags_on -Wall -Wextra)
|
|
endif()
|
|
list(APPEND _qt_compiler_warning_flags_off -w)
|
|
endif()
|
|
|
|
set(_qt_compiler_warning_flags_condition
|
|
"$<BOOL:$<TARGET_PROPERTY:QT_COMPILE_OPTIONS_DISABLE_WARNINGS>>")
|
|
set(_qt_compiler_warning_flags_genex
|
|
"$<IF:${_qt_compiler_warning_flags_condition},${_qt_compiler_warning_flags_off},${_qt_compiler_warning_flags_on}>")
|
|
|
|
# Need to replace semicolons so that the list is not wrongly expanded in the add_compile_options
|
|
# call.
|
|
string(REPLACE ";" "$<SEMICOLON>"
|
|
_qt_compiler_warning_flags_genex "${_qt_compiler_warning_flags_genex}")
|
|
add_compile_options(${_qt_compiler_warning_flags_genex})
|