Fix qplugin autotest on Windows

Since Qt 5.0.0 we never built the test plugins on Windows, because we
checked for the existence of QtCore[d]4.dll, and the actual test does
not complain if it cannot find any plugins.
Use the right conditions to check for debug/release Qt builds on
Windows. Use subdirs dependencies on every platform and then actually
pass the right variable to SUBDIRS. Clean up the pro file while we're at
it.

Change-Id: I099f30afd445fbf43dc5677d256ffe55b27639b3
Reviewed-by: Simon Hausmann <simon.hausmann@qt.io>

tests/auto/corelib/plugin/qplugin/qplugin.pro

@@ -1,28 +1,17 @@
-QT = core
 TEMPLATE = subdirs
+TESTPLUGINS =
+
 win32 {
-    exists($$[QT_INSTALL_LIBS/get]/QtCore4.dll) {
-        SUBDIRS = releaseplugin
-    }
-    exists($$[QT_INSTALL_LIBS/get]/QtCored4.dll) {
-        SUBDIRS += debugplugin
-    }
+    contains(QT_CONFIG, debug): TESTPLUGINS += debugplugin
+    contains(QT_CONFIG, release): TESTPLUGINS += releaseplugin
+} else:osx {
+    CONFIG(debug, debug|release): TESTPLUGINS += debugplugin
+    CONFIG(release, debug|release): TESTPLUGINS += releaseplugin
+} else {
+    TESTPLUGINS = debugplugin releaseplugin
 }
-mac {
-    CONFIG(debug, debug|release): {
-         SUBDIRS += debugplugin 
-         tst_qplugin_pro.depends += debugplugin
-    }
-    CONFIG(release, debug|release): {
-        SUBDIRS += releaseplugin 
-        tst_qplugin_pro.depends += releaseplugin
-    }
-}
-!win32:!mac:{
-    SUBDIRS = debugplugin releaseplugin
-    tst_qplugin_pro.depends += debugplugin releaseplugin
-} 
-SUBDIRS += tst_qplugin.pro
 
+SUBDIRS += main $$TESTPLUGINS
+main.file = tst_qplugin.pro
+main.depends = $$TESTPLUGINS
 
-CONFIG += parallel_test